ad_page_contract {
  This is the main page for the package.  It displays all entries
  provides links to create, edit and delete these

  @author Gustaf Neumann (gustaf.neumann@wu-wien.ac.at)
  @creation-date Oct 23, 2005
  @cvs-id $Id: index.vuh,v 1.6 2006/02/08 13:33:21 gustafn Exp $

  @param object_type show objects of this class and its subclasses
} -query {
  object_type:optional
  folder_id:optional
}

if {![info exists object_type]} {
  set object_type ::xowiki::Page
}
if {![info exists folder_id]} {
  set folder_id [$object_type require_folder -name xowiki]
}

set path [ns_urldecode [ad_conn path_info]]
#ns_log notice "-- path=<$path>"
if {$path ne ""} {
  set item_id [::Generic::CrItem lookup -title $path -parent_id $folder_id]

  if {$item_id == 0} {
    if {[regexp {^(..)/(.*)$} $path _ lang name]} {
      set title $lang:$name
    } elseif {![regexp {^..:} $path]} {
      set title [string range [lang::conn::locale] 0 1]:$path 
    }
    if {[info exists title]} {
      set item_id [::Generic::CrItem lookup -title $title -parent_id $folder_id]
    }
  }
  #ns_log notice "-- path=<$path> item_id=$item_id"
  if {$item_id != 0} {
    rp_form_put item_id $item_id
    rp_form_put folder_id $folder_id
    rp_internal_redirect "/packages/xowiki/www/view"
    ad_script_abort
  }
}